// 最短の距離を求めるシミュレーション

class Point {
    float x,y;
    int[] link;
    Point(float xx, float yy){
	x = xx;
	y = yy;
	link = new int[3];
    }
}

int WINWIDTH = 500;
int WINHEIGHT = 500;
int CONTROLHEIGHT = 30;

Point[] points;
int npoints;
int selind;
int ndots = 7;
boolean control = false;

void setup()
{
    PFont fontA = loadFont("CourierNew36.vlw");
    textFont(fontA, 20);
    size(WINWIDTH,WINHEIGHT+CONTROLHEIGHT);
    points = new Point[1000];
    initialize(ndots);
}

void initialize(int n)
{
    int i;
    for(npoints=0;npoints<n;npoints++){
	points[npoints] = new Point(random(500),random(500));
    }
    for(i=0;i<npoints-2;i++){
	//Point p = new Point(250,250);
	Point p = new Point(random(500),random(500));
	points[npoints+i] = p;
	p.link[0] = (i == 0 ? 0 : i+1);
	p.link[1] = (i == 0 ? 1 : npoints+i-1);
	p.link[2] = (i == npoints-3 ? npoints-1 : npoints+i+1);
    }
    loop();
}

void draw()
{
    display();
    movepoint();
    reconnect();
}

void display()
{
    background(213,200,255);
    smooth();
    fill(0,0,0);
    for(int i=0;i<npoints-2;i++){
	Point p = points[npoints+i];
	for(int j=0;j<3;j++){
	    Point q = points[p.link[j]];
	    line(p.x,p.y+CONTROLHEIGHT,q.x,q.y+CONTROLHEIGHT);
	}
    }
    fill(0,0,255);
    for(int i=0;i<npoints-2;i++){
	Point p = points[npoints+i];
	ellipse(p.x,p.y+CONTROLHEIGHT,5,5);
    }
    fill(255,255,0);
    for(int i=0;i<npoints;i++){
	Point p = points[i];
	ellipse(p.x,p.y+CONTROLHEIGHT,10,10);
    }
    fill(100,100,100);
    rect(30,10,WINWIDTH-34,5);
    
    fill(200,200,200);
    rect(ndots*10,4,16,16);
    fill(0,0,0);
    text(ndots,4,18);
}

void movepoint()
{
    for(int i=0;i<npoints-2;i++){
	float origx = points[npoints+i].x;
	float origy = points[npoints+i].y;
	float newx = origx;
	float newy = origy;
	float t = total();
	for(int x = -1;x<=1;x++){
	    for(int y = -1;y<=1;y++){
		points[npoints+i].x = origx + x;
		points[npoints+i].y = origy + y;
		float tt = total();
		if(tt < t){
		    newx = origx + x;
		    newy = origy + y;
		    t = tt;
		}
	    }
	}
	points[npoints+i].x = newx;
	points[npoints+i].y = newy;
    }
}

void reconnect()
{
    for(int i=0;i<npoints-3;i++){
	int p1ind = npoints+i;
	Point p1 = points[p1ind];
	for(int j=0;j<3;j++){
	    int p2ind = p1.link[j];
	    if(p2ind >= npoints){
		Point p2 = points[p2ind];
		if(dist(p1,p2) < 1.0){
		    int c = (random(2) > 1.0 ? 1 : 0);
		    int ind1;
		    for(ind1=0;ind1<3;ind1++){
			if(p1.link[ind1] == p2ind) continue;
			if(c-- == 0) break;
		    }

		    c = (random(2) > 1.0 ? 1 : 0);
		    int ind2;
		    for(ind2=0;ind2<3;ind2++){
			if(p2.link[ind2] == p1ind) continue;
			if(c-- == 0) break;
		    }

		    if(p1.link[ind1] >= npoints){
			Point p = points[p1.link[ind1]];
			for(int k=0;k<3;k++){
			    if(p.link[k] == p1ind){
				p.link[k] = p2ind;
				break;
			    }
			}
		    }
		    if(p2.link[ind2] >= npoints){
			Point p = points[p2.link[ind2]];
			for(int k=0;k<3;k++){
			    if(p.link[k] == p2ind){
				p.link[k] = p1ind;
				break;
			    }
			}
		    }

		    int tmp = p1.link[ind1];
		    p1.link[ind1] = p2.link[ind2];
		    p2.link[ind2] = tmp;
		}
	    }
	}
    }
}

float dist2(Point p1,Point p2)
{
    return (p1.x - p2.x) * (p1.x - p2.x) + (p1.y - p2.y) * (p1.y - p2.y);
}

float dist(Point p1,Point p2)
{
    return sqrt(dist2(p1,p2));
}

float total(){
    float v = 0.0;
    for(int i=0;i<npoints-2;i++){
	int p1ind = npoints+i;
	Point p1 = points[p1ind];
	for(int j=0;j<3;j++){
	    int p2ind = p1.link[j];
	    Point p2 = points[p2ind];
	    if(p2ind < npoints)
		v += dist(p1,p2);
	    else if(p1ind < p2ind)
		v += dist(p1,p2);
	}
    }
    return v;
}

void mousePressed(){
    if(mouseY < CONTROLHEIGHT){
	control = true;
    }
    else {
	float d = 0.0;
	control = false;
	Point p = new Point(mouseX,mouseY-CONTROLHEIGHT);
	for(int i=0;i<npoints;i++){
	    float dst = dist(p,points[i]);
	    if(dst < d || d == 0.0){
		d = dst;
		selind = i;
	    }
	}
	points[selind].x = mouseX;
	points[selind].y = mouseY-CONTROLHEIGHT;
    }
    
}

void mouseDragged(){
    if(control){
	ndots = mouseX / 10;
	if(ndots < 3) ndots = 3;
    }
    else {
	points[selind].x = mouseX;
	points[selind].y = mouseY-CONTROLHEIGHT;
    }
    
}

void mouseReleased(){
    if(control){
	ndots = mouseX / 10;
	if(ndots < 3) ndots = 3;
	initialize(ndots);
    }
}